;;; timbuk.el --- major mode for editing timbuk source in Emacs

;; Copyright (C) 1993, 94, 95, 96, 97, 98, 1999, 2000 Free Software Foundation, Inc.

;; Author: Espen Skoglund <esk@gnu.org>
;; Keywords: languages

;; This file is part of GNU Emacs.

;; GNU Emacs is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation; either version 2, or (at your option)
;; any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs; see the file COPYING.  If not, write to
;; the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
;; Boston, MA 02111-1307, USA.

;;; Commentary:

;; USAGE
;; =====

;; Emacs should enter Timbuk mode when you find a Timbuk source file.
;; When you have entered Timbuk mode, you may get more info by pressing
;; C-h m. You may also get online help describing various functions by:
;; C-h f <Name of function you want described>

;; If you want to customize Timbuk mode to fit you better, you may add
;; these lines (the values of the variables presented here are the defaults):
;;
;; ;; User customization for Timbuk mode
;; (setq timbuk-indent-level       3
;;       timbuk-case-indent        2
;;       timbuk-auto-newline       nil
;;       timbuk-tab-always-indent  t
;;       timbuk-auto-endcomments   t
;;       timbuk-auto-lineup        '(all)
;;       timbuk-toggle-completions nil
;;       timbuk-type-keywords      '("array" "file" "packed" "char" 
;; 				     "integer" "real" "string" "record")
;;       timbuk-start-keywords     '("begin" "end" "function" "procedure"
;; 				     "repeat" "until" "while" "read" "readln"
;; 				     "reset" "rewrite" "write" "writeln")
;;       timbuk-separator-keywords '("downto" "else" "mod" "div" "then"))

;; KNOWN BUGS / BUGREPORTS
;; =======================
;; As far as I know, there are no bugs in the current version of this
;; package.  This may not be true however, since I never use this mode
;; myself and therefore would never notice them anyway.   If you do
;; find any bugs, you may submit them to: esk@gnu.org as well as to
;; bug-gnu-emacs@gnu.org.

;;; Code:

(defgroup timbuk nil
  "Major mode for editing Timbuk source in Emacs"
  :group 'languages)

(defvar timbuk-mode-abbrev-table nil
  "Abbrev table in use in Timbuk-mode buffers.")
(define-abbrev-table 'timbuk-mode-abbrev-table ())

(defvar timbuk-mode-map ()
  "Keymap used in Timbuk mode.")
(if timbuk-mode-map
    ()
  (setq timbuk-mode-map (make-sparse-keymap))
  (define-key timbuk-mode-map ";"        'electric-timbuk-semi-or-dot)
  (define-key timbuk-mode-map "."        'electric-timbuk-semi-or-dot)
  (define-key timbuk-mode-map ":"        'electric-timbuk-colon)
  (define-key timbuk-mode-map "="        'electric-timbuk-equal)
  (define-key timbuk-mode-map "#"        'electric-timbuk-hash)
  (define-key timbuk-mode-map "\r"       'electric-timbuk-terminate-line)
  (define-key timbuk-mode-map "\t"       'electric-timbuk-tab)
  (define-key timbuk-mode-map "\M-\t"    'timbuk-complete-word)
  (define-key timbuk-mode-map "\M-?"     'timbuk-show-completions)
  (define-key timbuk-mode-map "\177"     'backward-delete-char-untabify)
  (define-key timbuk-mode-map "\M-\C-h"  'timbuk-mark-defun)
  (define-key timbuk-mode-map "\C-c\C-b" 'timbuk-insert-block)
  (define-key timbuk-mode-map "\M-*"     'timbuk-star-comment)
  (define-key timbuk-mode-map "\C-c\C-c" 'timbuk-comment-area)
  (define-key timbuk-mode-map "\C-c\C-u" 'timbuk-uncomment-area)
  (define-key timbuk-mode-map "\M-\C-a"  'timbuk-beg-of-defun)
  (define-key timbuk-mode-map "\M-\C-e"  'timbuk-end-of-defun)
  (define-key timbuk-mode-map "\C-c\C-d" 'timbuk-goto-defun)
  (define-key timbuk-mode-map "\C-c\C-o" 'timbuk-outline)
;;; A command to change the whole buffer won't be used terribly
;;; often, so no need for a key binding.
;  (define-key timbuk-mode-map "\C-cd"    'timbuk-downcase-keywords)
;  (define-key timbuk-mode-map "\C-cu"    'timbuk-upcase-keywords)
;  (define-key timbuk-mode-map "\C-cc"    'timbuk-capitalize-keywords)
  )

(defvar timbuk-imenu-generic-expression
  '("^[ \t]*\\(Automaton\\)[ \t\n]+\\([a-zA-Z0-9_.:]+\\)" . (2))
  "Imenu expression for Timbuk-mode.  See `imenu-generic-expression'.")

(defvar timbuk-keywords
  '("Ops" "Vars" "TRS" "Automaton" "States" "Final" "Transitions" "Description" "->" "--" "Prior"))

;;;
;;; Regular expressions used to calculate indent, etc.
;;;
(defconst timbuk-symbol-re      "\\<[a-zA-Z_][a-zA-Z_0-9.]*\\>")
(defconst timbuk-beg-block-re   "\\<\\(begin\\|case\\|record\\|repeat\\)\\>")
(defconst timbuk-end-block-re   "\\<\\(end\\|until\\)\\>")
(defconst timbuk-declaration-re "\\<\\(Ops\\|Vars\\|States\\|Transitions\\)\\>")
(defconst timbuk-progbeg-re     "\\<\\program\\>")
(defconst timbuk-defun-re       "\\<\\(TRS\\|Automaton\\)\\>")
(defconst timbuk-sub-block-re   "\\<\\(if\\|else\\|for\\|while\\|with\\)\\>")
(defconst timbuk-noindent-re    "\\<\\(begin\\|end\\|until\\|else\\)\\>")
(defconst timbuk-nosemi-re      "\\<\\(begin\\|repeat\\|then\\|do\\|else\\)\\>")
(defconst timbuk-autoindent-lines-re
  "\\<\\(label\\|var\\|type\\|const\\|until\\|end\\|begin\\|repeat\\|else\\)\\>")

;;; Strings used to mark beginning and end of excluded text
(defconst timbuk-exclude-str-start "{-----\\/----- EXCLUDED -----\\/-----")
(defconst timbuk-exclude-str-end " -----/\\----- EXCLUDED -----/\\-----}")

(defvar timbuk-mode-syntax-table nil
  "Syntax table in use in Timbuk-mode buffers.")

(if timbuk-mode-syntax-table
    ()
  (setq timbuk-mode-syntax-table (make-syntax-table))
  (modify-syntax-entry ?\\ "."   timbuk-mode-syntax-table)
  (modify-syntax-entry ?( "()1"  timbuk-mode-syntax-table)  
  (modify-syntax-entry ?) ")(4"  timbuk-mode-syntax-table)
  (modify-syntax-entry ?* ". 23b" timbuk-mode-syntax-table)
  (modify-syntax-entry ?{ "<"    timbuk-mode-syntax-table)
  (modify-syntax-entry ?} ">"    timbuk-mode-syntax-table)
  (modify-syntax-entry ?+ "."    timbuk-mode-syntax-table)
  (modify-syntax-entry ?- "."    timbuk-mode-syntax-table)
  (modify-syntax-entry ?= "."    timbuk-mode-syntax-table)
  (modify-syntax-entry ?% "."    timbuk-mode-syntax-table)
  (modify-syntax-entry ?< "."    timbuk-mode-syntax-table)
  (modify-syntax-entry ?> "."    timbuk-mode-syntax-table)
  (modify-syntax-entry ?& "."    timbuk-mode-syntax-table)
  (modify-syntax-entry ?| "."    timbuk-mode-syntax-table)
  (modify-syntax-entry ?_ "_"    timbuk-mode-syntax-table)
  (modify-syntax-entry ?\' "\""  timbuk-mode-syntax-table))

(defconst timbuk-font-lock-keywords (purecopy
  (list
   '("^[ \t]*\\(TRS\\|Automaton\\)\\>[ \t]*\\([a-z]\\)"
     1 font-lock-keyword-face)
   '("^[ \t]*\\(TRS\\|Automaton\\)\\>[ \t]*\\([a-z][a-z0-9_]*\\)"
     3 font-lock-function-name-face t)
   (cons (concat "\\<\\(States\\|Final\\|Ops\\|Vars\\|"
		 "Transitions\\|Description\\)\\>")
	 'font-lock-type-face)
   '("\\<\\([0-9]+\\)[ \t]*:" 1 font-lock-variable-name-face)
))
  "Additional expressions to highlight in Timbuk mode.")
(put 'timbuk-mode 'font-lock-defaults '(timbuk-font-lock-keywords nil t))

(defcustom timbuk-indent-level 3
  "*Indentation of Timbuk statements with respect to containing block."
  :type 'integer
  :group 'timbuk)

(defcustom timbuk-case-indent 2
  "*Indentation for case statements."
  :type 'integer
  :group 'timbuk)

(defcustom timbuk-auto-newline nil
  "*Non-nil means automatically insert newlines in certain cases.
These include after semicolons and after the punctuation mark after an `end'."
  :type 'boolean
  :group 'timbuk)

(defcustom timbuk-indent-nested-functions t
  "*Non-nil means nested functions are indented."
  :type 'boolean
  :group 'timbuk)

(defcustom timbuk-tab-always-indent t
  "*Non-nil means TAB in Timbuk mode should always reindent the current line.
If this is nil, TAB inserts a tab if it is at the end of the line
and follows non-whitespace text."
  :type 'boolean
  :group 'timbuk)

(defcustom timbuk-auto-endcomments t
  "*Non-nil means automatically insert comments after certain `end's.
Specifically, this is done after the ends of cases statements and functions.
The name of the function or case is included between the braces."
  :type 'boolean
  :group 'timbuk)

(defcustom timbuk-auto-lineup '(all)
  "*List of contexts where auto lineup of :'s or ='s should be done.
Elements can be of type: 'paramlist', 'declaration' or 'case', which will
do auto lineup in parameterlist, declarations or case-statements
respectively. The word 'all' will do all lineups. '(case paramlist) for
instance will do lineup in case-statements and parameterlist, while '(all)
will do all lineups."
  :type '(set :extra-offset 8
	      (const :tag "Everything" all)
	      (const :tag "Parameter lists" paramlist)
	      (const :tag "Decalrations" declaration)
	      (const :tag "Case statements" case))
  :group 'timbuk)

(defcustom timbuk-toggle-completions nil
  "*Non-nil means \\<timbuk-mode-map>\\[timbuk-complete-word] should try all possible completions one by one.
Repeated use of \\[timbuk-complete-word] will show you all of them.
Normally, when there is more than one possible completion,
it displays a list of all possible completions."
  :type 'boolean
  :group 'timbuk)

(defcustom timbuk-type-keywords
  '("array" "file" "packed" "char" "integer" "real" "string" "record")
  "*Keywords for types used when completing a word in a declaration or parmlist.
These include integer, real, char, etc.
The types defined within the Timbuk program
are handled in another way, and should not be added to this list."
  :type '(repeat (string :tag "Keyword"))
  :group 'timbuk)

(defcustom timbuk-start-keywords
  '("begin" "end" "function" "procedure" "repeat" "until" "while"
    "read" "readln" "reset" "rewrite" "write" "writeln")
  "*Keywords to complete when standing at the first word of a statement.
These are keywords such as begin, repeat, until, readln.
The procedures and variables defined within the Timbuk program
are handled in another way,  and should not be added to this list."
  :type '(repeat (string :tag "Keyword"))
  :group 'timbuk)

(defcustom timbuk-separator-keywords
  '("downto" "else" "mod" "div" "then")
  "*Keywords to complete when NOT standing at the first word of a statement.
These are keywords such as downto, else, mod, then.
Variables and function names defined within the Timbuk program
are handled in another way, and should not be added to this list."
  :type '(repeat (string :tag "Keyword"))
  :group 'timbuk)


;;;
;;;  Macros
;;;

(defsubst timbuk-get-beg-of-line (&optional arg)
  (save-excursion
    (beginning-of-line arg)
    (point)))

(defsubst timbuk-get-end-of-line (&optional arg)
  (save-excursion
    (end-of-line arg)
    (point)))

(defun timbuk-declaration-end ()
  (let ((nest 1))
    (while (and (> nest 0)
		(re-search-forward 
		 "[:=]\\|\\(\\<record\\>\\)\\|\\(\\<end\\>\\)" 
		 (save-excursion (end-of-line 2) (point)) t))
      (cond ((match-beginning 1) (setq nest (1+ nest)))
	    ((match-beginning 2) (setq nest (1- nest)))
	    ((looking-at "[^(\n]+)") (setq nest 0))))))


(defun timbuk-declaration-beg ()
  (let ((nest 1))
    (while (and (> nest 0)
		(re-search-backward "[:=]\\|\\<\\(type\\|var\\|label\\|const\\)\\>\\|\\(\\<record\\>\\)\\|\\(\\<end\\>\\)" (timbuk-get-beg-of-line 0) t))
      (cond ((match-beginning 1) (setq nest 0))
	    ((match-beginning 2) (setq nest (1- nest)))
	    ((match-beginning 3) (setq nest (1+ nest)))))
    (= nest 0)))

  
(defsubst timbuk-within-string ()
  (save-excursion
    (nth 3 (parse-partial-sexp (timbuk-get-beg-of-line) (point)))))


;;;###autoload
(defun timbuk-mode ()
  "Major mode for editing Timbuk code. \\<timbuk-mode-map>
TAB indents for Timbuk code.  Delete converts tabs to spaces as it moves back.

\\[timbuk-complete-word] completes the word around current point with respect \
to position in code
\\[timbuk-show-completions] shows all possible completions at this point.

Other useful functions are:

\\[timbuk-mark-defun]\t- Mark function.
\\[timbuk-insert-block]\t- insert begin ... end;
\\[timbuk-star-comment]\t- insert (* ... *)
\\[timbuk-comment-area]\t- Put marked area in a comment, fixing nested comments.
\\[timbuk-uncomment-area]\t- Uncomment an area commented with \
\\[timbuk-comment-area].
\\[timbuk-beg-of-defun]\t- Move to beginning of current function.
\\[timbuk-end-of-defun]\t- Move to end of current function.
\\[timbuk-goto-defun]\t- Goto function prompted for in the minibuffer.
\\[timbuk-outline]\t- Enter timbuk-outline-mode (see also timbuk-outline).

Variables controlling indentation/edit style:

 timbuk-indent-level (default 3)
    Indentation of Timbuk statements with respect to containing block.
 timbuk-case-indent (default 2)
    Indentation for case statements.
 timbuk-auto-newline (default nil)
    Non-nil means automatically newline after semicolons and the punctuation
    mark after an end.
 timbuk-indent-nested-functions (default t)
    Non-nil means nested functions are indented.
 timbuk-tab-always-indent (default t)
    Non-nil means TAB in Timbuk mode should always reindent the current line,
    regardless of where in the line point is when the TAB command is used.
 timbuk-auto-endcomments (default t)
    Non-nil means a comment { ... } is set after the ends which ends cases and
    functions. The name of the function or case will be set between the braces.
 timbuk-auto-lineup (default t)
    List of contexts where auto lineup of :'s or ='s should be done.

See also the user variables timbuk-type-keywords, timbuk-start-keywords and
timbuk-separator-keywords.

Turning on Timbuk mode calls the value of the variable timbuk-mode-hook with
no args, if that value is non-nil."
  (interactive)
  (kill-all-local-variables)
  (use-local-map timbuk-mode-map)
  (setq major-mode 'timbuk-mode)
  (setq mode-name "Timbuk")
  (setq local-abbrev-table timbuk-mode-abbrev-table)
  (set-syntax-table timbuk-mode-syntax-table)
  (make-local-variable 'indent-line-function)
  (setq indent-line-function 'timbuk-indent-line)
  (make-local-variable 'comment-indent-function)
  (setq comment-indent-function 'timbuk-indent-comment)
  (make-local-variable 'parse-sexp-ignore-comments)
  (setq parse-sexp-ignore-comments nil)
  (make-local-variable 'blink-matching-paren-dont-ignore-comments)
  (setq blink-matching-paren-dont-ignore-comments t)
  (make-local-variable 'case-fold-search)
  (setq case-fold-search t)
  (make-local-variable 'comment-start)
  (setq comment-start "{")
  (make-local-variable 'comment-start-skip)
  (setq comment-start-skip "(\\*+ *\\|{ *")
  (make-local-variable 'comment-end)
  (setq comment-end "}")
  ;; Font lock support
  (make-local-variable 'font-lock-defaults)
  (setq font-lock-defaults '(timbuk-font-lock-keywords nil t))
  ;; Imenu support
  (make-local-variable 'imenu-generic-expression)
  (setq imenu-generic-expression timbuk-imenu-generic-expression)
  (setq imenu-case-fold-search t)
  (run-hooks 'timbuk-mode-hook))



;;;
;;;  Electric functions
;;;
(defun electric-timbuk-terminate-line ()
  "Terminate line and indent next line."
  (interactive)
  ;; First, check if current line should be indented
  (save-excursion
    (beginning-of-line)
    (skip-chars-forward " \t")
    (if (looking-at timbuk-autoindent-lines-re)
	(timbuk-indent-line)))
  (delete-horizontal-space) ; Removes trailing whitespaces
  (newline)
  ;; Indent next line
  (timbuk-indent-line)
  ;; Maybe we should set some endcomments
  (if timbuk-auto-endcomments
      (timbuk-set-auto-comments))
  ;; Check if we shall indent inside comment
  (let ((setstar nil))
    (save-excursion
      (forward-line -1)
      (skip-chars-forward " \t")
      (cond ((looking-at "\\*[ \t]+)")
	     ;; Delete region between `*' and `)' if there is only whitespaces.
	     (forward-char 1)
	     (delete-horizontal-space))
	    ((and (looking-at "(\\*\\|\\*[^)]")
		  (not (save-excursion
			 (search-forward "*)" (timbuk-get-end-of-line) t))))
	     (setq setstar t))))
    ;; If last line was a star comment line then this one shall be too.
    (if (null setstar)	
	(timbuk-indent-line)
      (insert "*  "))))


(defun electric-timbuk-semi-or-dot ()
  "Insert `;' or `.' character and reindent the line."
  (interactive)
  (insert last-command-char)
  (save-excursion
    (beginning-of-line)
    (timbuk-indent-line))
  (if timbuk-auto-newline
      (electric-timbuk-terminate-line)))

(defun electric-timbuk-colon ()
  "Insert `:' and do all indentions except line indent on this line."
  (interactive)
  (insert last-command-char)
  ;; Do nothing if within string.
  (if (timbuk-within-string)
      ()
    (save-excursion
      (beginning-of-line)
      (timbuk-indent-line))
    (let ((timbuk-tab-always-indent nil))
      (timbuk-indent-command))))

(defun electric-timbuk-equal ()
  "Insert `=', and do indention if within type declaration."
  (interactive)
  (insert last-command-char)
  (if (eq (car (timbuk-calculate-indent)) 'declaration)
      (let ((timbuk-tab-always-indent nil))
	(timbuk-indent-command))))

(defun electric-timbuk-hash ()
  "Insert `#', and indent to column 0 if this is a CPP directive."
  (interactive)
  (insert last-command-char)
  (if (save-excursion (beginning-of-line) (looking-at "^[ \t]*#"))
      (save-excursion (beginning-of-line)
		      (delete-horizontal-space))))

(defun electric-timbuk-tab ()
  "Function called when TAB is pressed in Timbuk mode."
  (interactive)
  ;; Do nothing if within a string or in a CPP directive.
  (if (or (timbuk-within-string)
	  (and (not (bolp))
	       (save-excursion (beginning-of-line) (eq (following-char) ?#))))
      (insert "\t")
    ;; If timbuk-tab-always-indent, indent the beginning of the line.
    (if timbuk-tab-always-indent
	(save-excursion
	  (beginning-of-line)
	  (timbuk-indent-line))
      (if (save-excursion
	    (skip-chars-backward " \t")
	    (bolp))
	  (timbuk-indent-line)
	(insert "\t")))
    (timbuk-indent-command)))



;;;
;;; Interactive functions
;;;
(defun timbuk-insert-block ()
  "Insert Timbuk begin ... end; block in the code with right indentation."
  (interactive)
  (insert "begin")
  (electric-timbuk-terminate-line)
  (save-excursion
    (newline)
    (insert "end;")
    (beginning-of-line)
    (timbuk-indent-line)))

(defun timbuk-star-comment ()
  "Insert Timbuk star comment at point."
  (interactive)
  (timbuk-indent-line)
  (insert "(*")
  (electric-timbuk-terminate-line)
  (save-excursion
    (electric-timbuk-terminate-line)
    (delete-horizontal-space)
    (insert ")"))
  (insert "  "))

(defun timbuk-mark-defun ()
  "Mark the current timbuk function (or procedure).
This puts the mark at the end, and point at the beginning."
  (interactive)
  (push-mark (point))
  (timbuk-end-of-defun)
  (push-mark (point))
  (timbuk-beg-of-defun)
  (if (fboundp 'zmacs-activate-region)
      (zmacs-activate-region)))

(defun timbuk-comment-area (start end)
  "Put the region into a Timbuk comment.
The comments that are in this area are \"deformed\":
`*)' becomes `!(*' and `}' becomes `!{'.
These deformed comments are returned to normal if you use
\\[timbuk-uncomment-area] to undo the commenting.

The commented area starts with `timbuk-exclude-str-start', and ends with
`timbuk-include-str-end'.  But if you change these variables,
\\[timbuk-uncomment-area] won't recognize the comments."
  (interactive "r")
  (save-excursion
    ;; Insert start and endcomments
    (goto-char end)
    (if (and (save-excursion (skip-chars-forward " \t") (eolp))
	     (not (save-excursion (skip-chars-backward " \t") (bolp))))
	(forward-line 1)
      (beginning-of-line))
    (insert timbuk-exclude-str-end)
    (setq end (point))
    (newline)
    (goto-char start)
    (beginning-of-line)
    (insert timbuk-exclude-str-start)
    (newline)
    ;; Replace end-comments within commented area
    (goto-char end)
    (save-excursion
      (while (re-search-backward "\\*)" start t)
	(replace-match "!(*" t t)))
    (save-excursion
      (while (re-search-backward "}" start t)
	(replace-match "!{" t t)))))

(defun timbuk-uncomment-area ()
  "Uncomment a commented area; change deformed comments back to normal.
This command does nothing if the pointer is not in a commented
area.  See also `timbuk-comment-area'."
  (interactive)
  (save-excursion
    (let ((start (point))
	  (end (point)))
      ;; Find the boundaries of the comment
      (save-excursion
	(setq start (progn (search-backward timbuk-exclude-str-start nil t)
			   (point)))
	(setq end (progn (search-forward timbuk-exclude-str-end nil t)
			 (point))))
      ;; Check if we're really inside a comment
      (if (or (equal start (point)) (<= end (point)))
	  (message "Not standing within commented area.")
	(progn
	  ;; Remove endcomment
	  (goto-char end)
	  (beginning-of-line)
	  (let ((pos (point)))
	    (end-of-line)
	    (delete-region pos (1+ (point))))
	  ;; Change comments back to normal
	  (save-excursion
	    (while (re-search-backward "!{" start t)
	      (replace-match "}" t t)))
	  (save-excursion
	    (while (re-search-backward "!(\\*" start t)
	      (replace-match "*)" t t)))
	  ;; Remove startcomment
	  (goto-char start)
	  (beginning-of-line)
	  (let ((pos (point)))
	    (end-of-line)
	    (delete-region pos (1+ (point)))))))))

(defun timbuk-beg-of-defun ()
  "Move backward to the beginning of the current function or procedure."
  (interactive)
  (catch 'found
    (if (not (looking-at (concat "\\s \\|\\s)\\|" timbuk-defun-re)))
	(forward-sexp 1))
    (let ((nest 0) (max -1) (func 0)
	  (reg (concat timbuk-beg-block-re "\\|" 
		       timbuk-end-block-re "\\|"
		       timbuk-defun-re)))
      (while (re-search-backward reg nil 'move)
	(cond ((let ((state (save-excursion
			      (parse-partial-sexp (point-min) (point)))))
		 (or (nth 3 state) (nth 4 state))) ; Inside string or comment
	       ())
	      ((match-end 1)                       ; begin|case|record|repeat
	       (if (and (looking-at "\\<record\\>") (>= max 0))
		   (setq func (1- func)))
	       (setq nest (1+ nest)
		     max (max nest max)))
	      ((match-end 2)                       ; end|until
	       (if (and (= nest max) (>= max 0))
		   (setq func (1+ func)))
	       (setq nest (1- nest)))
	      ((match-end 3)                       ; function|procedure
	       (if (= 0 func)
		   (throw 'found t)
		 (setq func (1- func)))))))
    nil))

(defun timbuk-end-of-defun ()
  "Move forward to the end of the current function or procedure."
  (interactive)
  (if (looking-at "\\s ")
      (forward-sexp 1))
  (if (not (looking-at timbuk-defun-re))
      (timbuk-beg-of-defun))
  (forward-char 1)
  (let ((nest 0) (func 1)
	(reg (concat timbuk-beg-block-re "\\|" 
		     timbuk-end-block-re "\\|"
		     timbuk-defun-re)))
    (while (and (/= func 0)
		(re-search-forward reg nil 'move))
      (cond ((let ((state (save-excursion
			      (parse-partial-sexp (point-min) (point)))))
		 (or (nth 3 state) (nth 4 state))) ; Inside string or comment
	       ())
	    ((match-end 1)
	     (setq nest (1+ nest))
	     (if (save-excursion
		   (goto-char (match-beginning 0))
		   (looking-at "\\<record\\>"))
		 (setq func (1+ func))))
	    ((match-end 2)
	     (setq nest (1- nest))
	     (if (= nest 0)
		 (setq func (1- func))))
	    ((match-end 3)
	     (setq func (1+ func))))))
  (forward-line 1))

(defun timbuk-end-of-statement ()
  "Move forward to end of current statement."
  (interactive)
  (let ((parse-sexp-ignore-comments t)
	(nest 0) pos
	(regexp (concat "\\(" timbuk-beg-block-re "\\)\\|\\("
			timbuk-end-block-re "\\)")))
    (if (not (looking-at "[ \t\n]")) (forward-sexp -1))
    (or (looking-at timbuk-beg-block-re)
	;; Skip to end of statement
	(setq pos (catch 'found
		    (while t
		      (forward-sexp 1)
		      (cond ((looking-at "[ \t]*;")
			     (skip-chars-forward "^;")
			     (forward-char 1)
			     (throw 'found (point)))
			    ((save-excursion
			       (forward-sexp -1)
			       (looking-at timbuk-beg-block-re))
			     (goto-char (match-beginning 0))
			     (throw 'found nil))
			    ((eobp)
			     (throw 'found (point))))))))
    (if (not pos)
	;; Skip a whole block
	(catch 'found
	  (while t
	    (re-search-forward regexp nil 'move)
	    (setq nest (if (match-end 1) 
			   (1+ nest)
			 (1- nest)))
	    (cond ((eobp)
		   (throw 'found (point)))
		  ((= 0 nest)
		   (throw 'found (timbuk-end-of-statement))))))
      pos)))

(defun timbuk-downcase-keywords ()
  "Downcase all Timbuk keywords in the buffer."
  (interactive)
  (timbuk-change-keywords 'downcase-word))

(defun timbuk-upcase-keywords ()
  "Upcase all Timbuk keywords in the buffer."
  (interactive)
  (timbuk-change-keywords 'upcase-word))

(defun timbuk-capitalize-keywords ()
  "Capitalize all Timbuk keywords in the buffer."
  (interactive)
  (timbuk-change-keywords 'capitalize-word))

;; Change the keywords according to argument.
(defun timbuk-change-keywords (change-word)
  (save-excursion
    (let ((keyword-re (concat "\\<\\("
			      (mapconcat 'identity timbuk-keywords "\\|")
			      "\\)\\>")))
      (goto-char (point-min))
      (while (re-search-forward keyword-re nil t)
	(funcall change-word -1)))))



;;;
;;; Other functions
;;;
(defun timbuk-set-auto-comments ()
  "Insert `{ case }' or `{ NAME }' on this line if appropriate.
Insert `{ case }' if there is an `end' on the line which
ends a case block.  Insert `{ NAME }' if there is an `end'
on the line which ends a function or procedure named NAME."
  (save-excursion
    (forward-line -1)
    (skip-chars-forward " \t")
    (if (and (looking-at "\\<end;")
	     (not (save-excursion
		    (end-of-line)
		    (search-backward "{" (timbuk-get-beg-of-line) t))))
	(let ((type (car (timbuk-calculate-indent))))
	  (if (eq type 'declaration)
	      ()
	    (if (eq type 'case)
		;; This is a case block
		(progn
		  (end-of-line)
		  (delete-horizontal-space)
		  (insert " { case }"))
	      (let ((nest 1))
		;; Check if this is the end of a function
		(save-excursion
		  (while (not (or (looking-at timbuk-defun-re) (bobp)))
		    (backward-sexp 1)
		    (cond ((looking-at timbuk-beg-block-re)
			   (setq nest (1- nest)))
			  ((looking-at timbuk-end-block-re)
			   (setq nest (1+ nest)))))
		  (if (bobp)
		      (setq nest 1)))
		(if (zerop nest)
		    (progn
		      (end-of-line)
		      (delete-horizontal-space)
		      (insert " { ")
		      (let (b e)
			(save-excursion
			  (setq b (progn (timbuk-beg-of-defun)
					 (skip-chars-forward "^ \t")
					 (skip-chars-forward " \t")
					 (point))
				e (progn (skip-chars-forward "a-zA-Z0-9_")
					 (point))))
			(insert-buffer-substring (current-buffer) b e))
		      (insert " }"))))))))))



;;;
;;; Indentation
;;;
(defconst timbuk-indent-alist
  '((block . (+ ind timbuk-indent-level))
    (case . (+ ind timbuk-case-indent))
    (caseblock . ind) (cpp . 0)
    (declaration . (+ ind timbuk-indent-level))
    (paramlist . (timbuk-indent-paramlist t))
    (comment . (timbuk-indent-comment))
    (defun . ind) (contexp . ind)
    (unknown . ind) (string . 0) (progbeg . 0)))

(defun timbuk-indent-command ()
  "Indent for special part of code."
  (let* ((indent-str (timbuk-calculate-indent))
	 (type (car indent-str))
	 (ind (car (cdr indent-str))))
    (cond ((and (eq type 'paramlist)
		(or (memq 'all timbuk-auto-lineup)
		    (memq 'paramlist timbuk-auto-lineup)))
	   (timbuk-indent-paramlist)
	   (timbuk-indent-paramlist))
	  ((and (eq type 'declaration)
		(or (memq 'all timbuk-auto-lineup)
		    (memq 'declaration  timbuk-auto-lineup)))
	   (timbuk-indent-declaration))
	  ((and (eq type 'case) (not (looking-at "^[ \t]*$"))
		(or (memq 'all timbuk-auto-lineup)
		    (memq 'case timbuk-auto-lineup)))
	   (timbuk-indent-case)))
    (if (looking-at "[ \t]+$")
	(skip-chars-forward " \t"))))

(defun timbuk-indent-line ()
  "Indent current line as a Timbuk statement."
  (let* ((indent-str (timbuk-calculate-indent))
	 (type (car indent-str))
	 (ind (car (cdr indent-str))))
    ;; Labels should not be indented.
    (if (and (looking-at "^[0-9a-zA-Z]+[ \t]*:[^=]")
	     (not (eq type 'declaration)))
	(search-forward ":" nil t))
    (delete-horizontal-space)
    (cond (; Some things should not be indented
	   (or (and (eq type 'declaration) (looking-at timbuk-declaration-re))
	       (eq type 'cpp))
	   ())
	  (; Other things should have no extra indent
	   (looking-at timbuk-noindent-re)
	   (indent-to ind))
	  (; Nested functions should be indented
	   (looking-at timbuk-defun-re)
	   (if (and timbuk-indent-nested-functions
		    (eq type 'defun))
	       (indent-to (+ ind timbuk-indent-level))
	     (indent-to ind)))
	  (; But most lines are treated this way
	   (indent-to (eval (cdr (assoc type timbuk-indent-alist))))
	   ))))

(defun timbuk-calculate-indent ()
  "Calculate the indent of the current Timbuk line.
Return a list of two elements: (INDENT-TYPE INDENT-LEVEL)."
  (save-excursion
    (let* ((parse-sexp-ignore-comments t)
	   (oldpos (point))
	   (state (save-excursion (parse-partial-sexp (point-min) (point))))
	   (nest 0) (par 0) (complete (looking-at "[ \t]*end\\>"))
	   (elsed (looking-at "[ \t]*else\\>")) (funccnt 0)
	   (did-func (looking-at "[ \t]*\\(procedure\\|function\\)\\>"))
	   (type (catch 'nesting
		   ;; Check if inside a string, comment or parenthesis
		   (cond ((nth 3 state) (throw 'nesting 'string))
			 ((nth 4 state) (throw 'nesting 'comment))
			 ((> (car state) 0)
			  (goto-char (scan-lists (point) -1 (car state)))
			  (setq par (1+ (current-column))))
			 ((save-excursion (beginning-of-line)
					  (eq (following-char) ?#))
			  (throw 'nesting 'cpp)))
		   ;; Loop until correct indent is found
		   (while t
		     (backward-sexp 1)
		     (cond (;--Escape from case statements
			    (and (looking-at "[A-Za-z0-9]+[ \t]*:[^=]")
				 (not complete)
				 (save-excursion (skip-chars-backward " \t")
						 (bolp))
				 (= (save-excursion
				      (end-of-line) (backward-sexp) (point))
				    (point))
				 (> (save-excursion (goto-char oldpos)
						    (beginning-of-line)
						    (point))
				    (point)))
			    (throw 'nesting 'caseblock))
			   (;--Beginning of program
			    (looking-at timbuk-progbeg-re)
			    (throw 'nesting 'progbeg))
			   (;--No known statements
			    (bobp)
			    (throw 'nesting 'progbeg))
			   (;--Nest block outwards
			    (looking-at timbuk-beg-block-re)
			    (if (= nest 0)
				(cond ((looking-at "case\\>")
				       (throw 'nesting 'case))
				      ((looking-at "record\\>")
				       (throw 'nesting 'declaration))
				      (t (throw 'nesting 'block)))
			      (if (and (looking-at "record\\>") (= nest 1))
				  (setq funccnt (1- funccnt)))
			      (setq nest (1- nest))))
			   (;--Nest block inwards
			    (looking-at timbuk-end-block-re)
			    (if (and (looking-at "end\\s ")
				     elsed (not complete))
				(throw 'nesting 'block))
			    (if (= nest 0)
				(setq funccnt (1+ funccnt)))
			    (setq complete t
				  nest (1+ nest)))
			   (;--Defun (or parameter list)
			    (and (looking-at timbuk-defun-re)
				 (progn (setq funccnt (1- funccnt)
					      did-func t)
					(or (bolp) (< funccnt 0))))
			    ;; Prevent searching whole buffer
			    (if (and (bolp) (>= funccnt 0))
				(throw 'nesting 'progbeg))
			    (if (= 0 par)
				(throw 'nesting 'defun)
			      (setq par 0)
			      (let ((n 0))
				(while (re-search-forward
					"\\(\\<record\\>\\)\\|\\<end\\>"
					oldpos t)
				  (if (match-end 1)
				      (setq n (1+ n)) (setq n (1- n))))
				(if (> n 0)
				    (throw 'nesting 'declaration)
				  (throw 'nesting 'paramlist)))))
			   (;--Declaration part
			    (and (looking-at timbuk-declaration-re)
				 (not did-func)
				 (= funccnt 0))
			    (if (save-excursion
				  (goto-char oldpos)
				  (forward-line -1)
				  (looking-at "^[ \t]*$"))
				(throw 'nesting 'unknown)
			      (throw 'nesting 'declaration)))
			   (;--If, else or while statement
			    (and (not complete)
				 (looking-at timbuk-sub-block-re))
			    (throw 'nesting 'block))
			   (;--Found complete statement
			    (save-excursion (forward-sexp 1)
					    (= (following-char) ?\;))
			    (setq complete t))
			   )))))

      ;; Return type of block and indent level.
      (if (> par 0)                               ; Unclosed Parenthesis 
	  (list 'contexp par)
	(list type (timbuk-indent-level))))))

(defun timbuk-indent-level ()
  "Return the indent-level the current statement has.
Do not count labels, case-statements or records."
  (save-excursion
    (beginning-of-line)
    (if (looking-at "[ \t]*[0-9a-zA-Z]+[ \t]*:[^=]")
	(search-forward ":" nil t)
      (if (looking-at ".*=[ \t]*record\\>")
	  (search-forward "=" nil t)))
    (skip-chars-forward " \t")
    (current-column)))

(defun timbuk-indent-comment ()
  "Return indent for current comment."
  (save-excursion
    (re-search-backward "\\((\\*\\)\\|{" nil t)
    (if (match-beginning 1)
	(1+ (current-column))
      (current-column))))

(defun timbuk-indent-case ()
  "Indent within case statements."
  (let ((savepos (point-marker))
	(end (prog2
		 (end-of-line)
		 (point-marker)
	       (re-search-backward "\\<case\\>" nil t)))
	(beg (point)) oldpos
	(ind 0))
    ;; Get right indent
    (while (< (point) end)
      (if (re-search-forward 
	   "^[ \t]*[^ \t,:]+[ \t]*\\(,[ \t]*[^ \t,:]+[ \t]*\\)*:"
	   (marker-position end) 'move)
	  (forward-char -1))
      (if (< (point) end)
	  (progn
	    (delete-horizontal-space)
	    (if (> (current-column) ind)
		(setq ind (current-column)))
	    (timbuk-end-of-statement))))
    (goto-char beg)
    (setq oldpos (marker-position end))
    ;; Indent all case statements
    (while (< (point) end)
      (if (re-search-forward
	   "^[ \t]*[^][ \t,\\.:]+[ \t]*\\(,[ \t]*[^ \t,:]+[ \t]*\\)*:"
	   (marker-position end) 'move)
	  (forward-char -1))
      (indent-to (1+ ind))
      (if (/= (following-char) ?:)
	  ()
	(forward-char 1)
	(delete-horizontal-space)
	(insert " "))
      (setq oldpos (point))
      (timbuk-end-of-statement))
    (goto-char savepos)))

(defun timbuk-indent-paramlist (&optional arg)
  "Indent current line in parameterlist.
If optional arg is non-nil, just return the
indent of the current line in parameterlist."
  (save-excursion
    (let* ((oldpos (point))
	   (stpos (progn (goto-char (scan-lists (point) -1 1)) (point)))
	   (stcol (1+ (current-column)))
	   (edpos (progn (timbuk-declaration-end) 
			 (search-backward ")" (timbuk-get-beg-of-line) t)
			 (point)))
	   (usevar (re-search-backward "\\<var\\>" stpos t)))
      (if arg (progn
		;; If arg, just return indent
		(goto-char oldpos)
		(beginning-of-line)
		(if (or (not usevar) (looking-at "[ \t]*var\\>"))
		    stcol (+ 4 stcol)))
	(goto-char stpos)
	(forward-char 1)
	(delete-horizontal-space)
	(if (and usevar (not (looking-at "var\\>")))
	    (indent-to (+ 4 stcol)))
	(timbuk-indent-declaration nil stpos edpos)))))

(defun timbuk-indent-declaration (&optional arg start end)
  "Indent current lines as declaration, lining up the `:'s or `='s."
  (let ((pos (point-marker)))
    (if (and (not (or arg start)) (not (timbuk-declaration-beg)))
	()
      (let ((lineup (if (or (looking-at "\\<var\\>\\|\\<record\\>") arg start) 
			":" "="))
	    (stpos (if start start
		       (forward-word 2) (backward-word 1) (point)))
	    (edpos (set-marker (make-marker)
			       (if end end
				 (max (progn (timbuk-declaration-end)
					     (point))
				      pos))))
	    ind)

	(goto-char stpos)
	;; Indent lines in record block
	(if arg
	    (while (<= (point) edpos)
	      (beginning-of-line)
	      (delete-horizontal-space)
	      (if (looking-at "end\\>")
		  (indent-to arg)
		(indent-to (+ arg timbuk-indent-level)))
	      (forward-line 1)))

	;; Do lineup
	(setq ind (timbuk-get-lineup-indent stpos edpos lineup))
	(goto-char stpos)
	(while (and (<= (point) edpos) (not (eobp)))
	  (if (search-forward lineup (timbuk-get-end-of-line) 'move)
	      (forward-char -1))
	  (delete-horizontal-space)
	  (indent-to ind)
	  (if (not (looking-at lineup))
	      (forward-line 1) ; No more indent if there is no : or =
	    (forward-char 1)
	    (delete-horizontal-space)
	    (insert " ")
	    ;; Indent record block
	    (if (looking-at "record\\>")
		(timbuk-indent-declaration (current-column)))
	    (forward-line 1)))))

    ;; If arg - move point
    (if arg (forward-line -1)
      (goto-char pos))))

;  "Return the indent level that will line up several lines within the region
;from b to e nicely. The lineup string is str."
(defun timbuk-get-lineup-indent (b e str)
  (save-excursion
    (let ((ind 0)
	  (reg (concat str "\\|\\(\\<record\\>\\)\\|" timbuk-defun-re)))
      (goto-char b)
      ;; Get rightmost position
      (while (< (point) e)
	(and (re-search-forward reg (min e (timbuk-get-end-of-line 2)) 'move)
	     (cond ((match-beginning 1)
		    ;; Skip record blocks
		    (timbuk-declaration-end))
		   ((match-beginning 2)
		    ;; We have entered a new procedure.  Exit.
		    (goto-char e))
		   (t
		    (goto-char (match-beginning 0))
		    (skip-chars-backward " \t")
		    (if (> (current-column) ind)
			(setq ind (current-column)))
		    (goto-char (match-end 0))
		    (end-of-line)
		    ))))
      ;; In case no lineup was found
      (if (> ind 0)
	  (1+ ind)
	;; No lineup-string found
	(goto-char b)
	(end-of-line)
	(skip-chars-backward " \t")
	(1+ (current-column))))))
    


;;;
;;; Completion
;;;
(defvar timbuk-str nil)
(defvar timbuk-all nil)
(defvar timbuk-pred nil)
(defvar timbuk-buffer-to-use nil)
(defvar timbuk-flag nil)

(defun timbuk-string-diff (str1 str2)
  "Return index of first letter where STR1 and STR2 differs."
  (catch 'done
    (let ((diff 0))
      (while t
	(if (or (> (1+ diff) (length str1))
		(> (1+ diff) (length str2)))
	    (throw 'done diff))
	(or (equal (aref str1 diff) (aref str2 diff))
	    (throw 'done diff))
	(setq diff (1+ diff))))))

;; Calculate all possible completions for functions if argument is `function',
;; completions for procedures if argument is `procedure' or both functions and
;; procedures otherwise.

(defun timbuk-func-completion (type)
  ;; Build regular expression for function/procedure names
  (if (string= timbuk-str "")
      (setq timbuk-str "[a-zA-Z_]"))
  (let ((timbuk-str (concat (cond
			     ((eq type 'procedure) "\\<\\(procedure\\)\\s +")
			     ((eq type 'function) "\\<\\(function\\)\\s +")
			     (t "\\<\\(function\\|procedure\\)\\s +"))
			    "\\<\\(" timbuk-str "[a-zA-Z0-9_.]*\\)\\>"))
	match)
    
    (if (not (looking-at "\\<\\(function\\|procedure\\)\\>"))
	(re-search-backward "\\<\\(function\\|procedure\\)\\>" nil t))
    (forward-char 1)

    ;; Search through all reachable functions
    (while (timbuk-beg-of-defun)
      (if (re-search-forward timbuk-str (timbuk-get-end-of-line) t)
	  (progn (setq match (buffer-substring (match-beginning 2)
					       (match-end 2)))
		 (if (or (null timbuk-pred)
			 (funcall timbuk-pred match))
		     (setq timbuk-all (cons match timbuk-all)))))
      (goto-char (match-beginning 0)))))

(defun timbuk-get-completion-decl ()
  ;; Macro for searching through current declaration (var, type or const)
  ;; for matches of `str' and adding the occurrence to `all'
  (let ((end (save-excursion (timbuk-declaration-end)
			     (point)))
	match)
    ;; Traverse lines
    (while (< (point) end)
      (if (re-search-forward "[:=]" (timbuk-get-end-of-line) t)
	  ;; Traverse current line
	  (while (and (re-search-backward 
		       (concat "\\((\\|\\<\\(var\\|type\\|const\\)\\>\\)\\|" 
			       timbuk-symbol-re)
		       (timbuk-get-beg-of-line) t)
		      (not (match-end 1)))
	    (setq match (buffer-substring (match-beginning 0) (match-end 0)))
	    (if (string-match (concat "\\<" timbuk-str) match)
		(if (or (null timbuk-pred)
			(funcall timbuk-pred match))
		    (setq timbuk-all (cons match timbuk-all))))))
      (if (re-search-forward "\\<record\\>" (timbuk-get-end-of-line) t)
	  (timbuk-declaration-end)
	(forward-line 1)))))

(defun timbuk-type-completion ()
  "Calculate all possible completions for types."
  (let ((start (point))
	goon)
    ;; Search for all reachable type declarations
    (while (or (timbuk-beg-of-defun)
	       (setq goon (not goon)))
      (save-excursion
	(if (and (< start (prog1 (save-excursion (timbuk-end-of-defun)
						 (point))
			    (forward-char 1)))
		 (re-search-forward
		  "\\<type\\>\\|\\<\\(begin\\|function\\|procedure\\)\\>"
		  start t)
		 (not (match-end 1)))
	    ;; Check current type declaration
	    (timbuk-get-completion-decl))))))

(defun timbuk-var-completion ()
  "Calculate all possible completions for variables (or constants)."
  (let ((start (point))
	goon twice)
    ;; Search for all reachable var declarations
    (while (or (timbuk-beg-of-defun)
	       (setq goon (not goon)))
      (save-excursion
	(if (> start (prog1 (save-excursion (timbuk-end-of-defun)
					    (point))))
	    () ; Declarations not reachable
	  (if (search-forward "(" (timbuk-get-end-of-line) t)
	      ;; Check parameterlist
		(timbuk-get-completion-decl))
	  (setq twice 2)
	  (while (>= (setq twice (1- twice)) 0)
	    (cond ((and (re-search-forward
			 (concat "\\<\\(var\\|const\\)\\>\\|"
				 "\\<\\(begin\\|function\\|procedure\\)\\>")
			 start t)
			(not (match-end 2)))
		   ;; Check var/const declarations
		   (timbuk-get-completion-decl))
		  ((match-end 2)
		   (setq twice 0)))))))))


(defun timbuk-keyword-completion (keyword-list)
  "Give list of all possible completions of keywords in KEYWORD-LIST."
  (mapcar '(lambda (s) 
	     (if (string-match (concat "\\<" timbuk-str) s)
		 (if (or (null timbuk-pred)
			 (funcall timbuk-pred s))
		     (setq timbuk-all (cons s timbuk-all)))))
	  keyword-list))

;; Function passed to completing-read, try-completion or
;; all-completions to get completion on STR. If predicate is non-nil,
;; it must be a function to be called for every match to check if this
;; should really be a match. If flag is t, the function returns a list
;; of all possible completions. If it is nil it returns a string, the
;; longest possible completion, or t if STR is an exact match. If flag
;; is 'lambda, the function returns t if STR is an exact match, nil
;; otherwise.

(defun timbuk-completion (timbuk-str timbuk-pred timbuk-flag)
  (save-excursion
    (let ((timbuk-all nil))
      ;; Set buffer to use for searching labels. This should be set
      ;; within functions which use timbuk-completions
      (set-buffer timbuk-buffer-to-use)

      ;; Determine what should be completed
      (let ((state (car (timbuk-calculate-indent))))
	(cond (;--Within a declaration or parameterlist
	       (or (eq state 'declaration) (eq state 'paramlist)
		   (and (eq state 'defun)
			(save-excursion
			  (re-search-backward ")[ \t]*:"
					      (timbuk-get-beg-of-line) t))))
	       (if (or (eq state 'paramlist) (eq state 'defun))
		   (timbuk-beg-of-defun))
	       (timbuk-type-completion)
	       (timbuk-keyword-completion timbuk-type-keywords))
	      (;--Starting a new statement
	       (and (not (eq state 'contexp))
		    (save-excursion
		      (skip-chars-backward "a-zA-Z0-9_.")
		      (backward-sexp 1)
		      (or (looking-at timbuk-nosemi-re)
			  (progn
			    (forward-sexp 1)
			    (looking-at "\\s *\\(;\\|:[^=]\\)")))))
	       (save-excursion (timbuk-var-completion))
	       (timbuk-func-completion 'procedure)
	       (timbuk-keyword-completion timbuk-start-keywords))
	      (t;--Anywhere else
	       (save-excursion (timbuk-var-completion))
	       (timbuk-func-completion 'function)
	       (timbuk-keyword-completion timbuk-separator-keywords))))
      
      ;; Now we have built a list of all matches. Give response to caller
      (timbuk-completion-response))))

(defun timbuk-completion-response ()
  (cond ((or (equal timbuk-flag 'lambda) (null timbuk-flag))
	 ;; This was not called by all-completions
	 (if (null timbuk-all)
	     ;; Return nil if there was no matching label
	     nil
	   ;; Get longest string common in the labels
	   (let* ((elm (cdr timbuk-all))
		  (match (car timbuk-all))
		  (min (length match))
		  tmp)
	     (if (string= match timbuk-str)
		 ;; Return t if first match was an exact match
		 (setq match t)
	       (while (not (null elm))
		 ;; Find longest common string
		 (if (< (setq tmp (timbuk-string-diff match (car elm))) min)
		     (progn
		       (setq min tmp)
		       (setq match (substring match 0 min))))
		 ;; Terminate with match=t if this is an exact match
		 (if (string= (car elm) timbuk-str)
		     (progn
		       (setq match t)
		       (setq elm nil))
		   (setq elm (cdr elm)))))
	     ;; If this is a test just for exact match, return nil ot t
	     (if (and (equal timbuk-flag 'lambda) (not (equal match 't)))
		 nil
	       match))))
	;; If flag is t, this was called by all-completions. Return
	;; list of all possible completions
	(timbuk-flag
	 timbuk-all)))

(defvar timbuk-last-word-numb 0)
(defvar timbuk-last-word-shown nil)
(defvar timbuk-last-completions nil)

(defun timbuk-complete-word ()
  "Complete word at current point.
\(See also `timbuk-toggle-completions', `timbuk-type-keywords',
`timbuk-start-keywords' and `timbuk-separator-keywords'.)"
  (interactive)
  (let* ((b (save-excursion (skip-chars-backward "a-zA-Z0-9_") (point)))
	 (e (save-excursion (skip-chars-forward "a-zA-Z0-9_") (point)))
	 (timbuk-str (buffer-substring b e))
	 ;; The following variable is used in timbuk-completion
	 (timbuk-buffer-to-use (current-buffer))
	 (allcomp (if (and timbuk-toggle-completions
			   (string= timbuk-last-word-shown timbuk-str))
		      timbuk-last-completions
		    (all-completions timbuk-str 'timbuk-completion)))
	 (match (if timbuk-toggle-completions
		    "" (try-completion
			timbuk-str (mapcar '(lambda (elm)
					      (cons elm 0)) allcomp)))))
    ;; Delete old string
    (delete-region b e)

    ;; Toggle-completions inserts whole labels
    (if timbuk-toggle-completions
	(progn
	  ;; Update entry number in list
	  (setq timbuk-last-completions allcomp
		timbuk-last-word-numb 
		(if (>= timbuk-last-word-numb (1- (length allcomp)))
		    0
		  (1+ timbuk-last-word-numb)))
	  (setq timbuk-last-word-shown (elt allcomp timbuk-last-word-numb))
	  ;; Display next match or same string if no match was found
	  (if (not (null allcomp))
	      (insert "" timbuk-last-word-shown)
	    (insert "" timbuk-str)
	    (message "(No match)")))
      ;; The other form of completion does not necessarily do that.

      ;; Insert match if found, or the original string if no match
      (if (or (null match) (equal match 't))
	  (progn (insert "" timbuk-str)
		 (message "(No match)"))
	(insert "" match))
      ;; Give message about current status of completion
      (cond ((equal match 't)
	     (if (not (null (cdr allcomp)))
		 (message "(Complete but not unique)")
	       (message "(Sole completion)")))
	    ;; Display buffer if the current completion didn't help 
	    ;; on completing the label.
	    ((and (not (null (cdr allcomp))) (= (length timbuk-str)
						(length match)))
	     (with-output-to-temp-buffer "*Completions*"
	       (display-completion-list allcomp))
	     ;; Wait for a keypress. Then delete *Completion*  window
	     (momentary-string-display "" (point))
	     (delete-window (get-buffer-window (get-buffer "*Completions*")))
	     )))))

(defun timbuk-show-completions ()
  "Show all possible completions at current point."
  (interactive)
  (let* ((b (save-excursion (skip-chars-backward "a-zA-Z0-9_") (point)))
	 (e (save-excursion (skip-chars-forward "a-zA-Z0-9_") (point)))
	 (timbuk-str (buffer-substring b e))
	 ;; The following variable is used in timbuk-completion
	 (timbuk-buffer-to-use (current-buffer))
	 (allcomp (if (and timbuk-toggle-completions
			   (string= timbuk-last-word-shown timbuk-str))
		      timbuk-last-completions
		    (all-completions timbuk-str 'timbuk-completion))))
    ;; Show possible completions in a temporary buffer.
    (with-output-to-temp-buffer "*Completions*"
      (display-completion-list allcomp))
    ;; Wait for a keypress. Then delete *Completion*  window
    (momentary-string-display "" (point))
    (delete-window (get-buffer-window (get-buffer "*Completions*")))))


(defun timbuk-get-default-symbol ()
  "Return symbol around current point as a string."
  (save-excursion
    (buffer-substring (progn
			(skip-chars-backward " \t")
			(skip-chars-backward "a-zA-Z0-9_")
			(point))
		      (progn
			(skip-chars-forward "a-zA-Z0-9_")
			(point)))))

(defun timbuk-build-defun-re (str &optional arg)
  "Return function/procedure starting with STR as regular expression.
With optional second arg non-nil, STR is the complete name of the instruction."
  (if arg
      (concat "^\\(function\\|procedure\\)[ \t]+\\(" str "\\)\\>")
    (concat "^\\(function\\|procedure\\)[ \t]+\\(" str "[a-zA-Z0-9_]*\\)\\>")))

;; Function passed to completing-read, try-completion or
;; all-completions to get completion on any function name. If
;; predicate is non-nil, it must be a function to be called for every
;; match to check if this should really be a match. If flag is t, the
;; function returns a list of all possible completions. If it is nil
;; it returns a string, the longest possible completion, or t if STR
;; is an exact match. If flag is 'lambda, the function returns t if
;; STR is an exact match, nil otherwise.

(defun timbuk-comp-defun (timbuk-str timbuk-pred timbuk-flag)
  (save-excursion
    (let ((timbuk-all nil)
	  match)

      ;; Set buffer to use for searching labels. This should be set
      ;; within functions which use timbuk-completions
      (set-buffer timbuk-buffer-to-use)

      (let ((timbuk-str timbuk-str))
	;; Build regular expression for functions
	(if (string= timbuk-str "")
	    (setq timbuk-str (timbuk-build-defun-re "[a-zA-Z_]"))
	  (setq timbuk-str (timbuk-build-defun-re timbuk-str)))
	(goto-char (point-min))
      
	;; Build a list of all possible completions
	(while (re-search-forward timbuk-str nil t)
	  (setq match (buffer-substring (match-beginning 2) (match-end 2)))
	  (if (or (null timbuk-pred)
		  (funcall timbuk-pred match))
	      (setq timbuk-all (cons match timbuk-all)))))

      ;; Now we have built a list of all matches. Give response to caller
      (timbuk-completion-response))))

(defun timbuk-goto-defun ()
  "Move to specified Timbuk function/procedure.
The default is a name found in the buffer around point."
  (interactive)
  (let* ((default (timbuk-get-default-symbol))
	 ;; The following variable is used in timbuk-comp-function
	 (timbuk-buffer-to-use (current-buffer))
	 (default (if (timbuk-comp-defun default nil 'lambda)
		      default ""))
	 (label (if (not (string= default ""))
		    ;; Do completion with default
		    (completing-read (concat "Label: (default " default ") ")
				     'timbuk-comp-defun nil t "")
		  ;; There is no default value. Complete without it
		  (completing-read "Label: "
				   'timbuk-comp-defun nil t ""))))
    ;; If there was no response on prompt, use default value
    (if (string= label "")
	(setq label default))
    ;; Goto right place in buffer if label is not an empty string
    (or (string= label "")
	(progn
	  (goto-char (point-min))
	  (re-search-forward (timbuk-build-defun-re label t))
	  (beginning-of-line)))))



;;;
;;; Timbuk-outline-mode
;;;
(defvar timbuk-outline-map nil "Keymap used in Timbuk Outline mode.")

(if timbuk-outline-map
    nil
  (if (boundp 'set-keymap-name)
      (set-keymap-name timbuk-outline-map 'timbuk-outline-map))
  (if (not (boundp 'set-keymap-parent))
      (setq timbuk-outline-map (copy-keymap timbuk-mode-map))
    (setq timbuk-outline-map (make-sparse-keymap))
    (set-keymap-parent timbuk-outline-map timbuk-mode-map))
  (define-key timbuk-outline-map "\M-\C-a"  'timbuk-outline-prev-defun)
  (define-key timbuk-outline-map "\M-\C-e"  'timbuk-outline-next-defun)
  (define-key timbuk-outline-map "\C-c\C-d" 'timbuk-outline-goto-defun)
  (define-key timbuk-outline-map "\C-c\C-s" 'timbuk-show-all)
  (define-key timbuk-outline-map "\C-c\C-h" 'timbuk-hide-other-defuns))

(defvar timbuk-outline-mode nil "Non-nil while using Timbuk Outline mode.")
(make-variable-buffer-local 'timbuk-outline-mode)
(set-default 'timbuk-outline-mode nil)
(if (not (assoc 'timbuk-outline-mode minor-mode-alist))
    (setq minor-mode-alist (append minor-mode-alist
				   (list '(timbuk-outline-mode " Outl")))))

(defun timbuk-outline (&optional arg)
  "Outline-line minor mode for Timbuk mode.
When in Timbuk Outline mode, portions
of the text being edited may be made invisible. \\<timbuk-outline-map>

Timbuk Outline mode provides some additional commands.

\\[timbuk-outline-prev-defun]\
\t- Move to previous function/procedure, hiding everything else.
\\[timbuk-outline-next-defun]\
\t- Move to next function/procedure, hiding everything else.
\\[timbuk-outline-goto-defun]\
\t- Goto function/procedure prompted for in minibuffer,
\t  hide all other functions.
\\[timbuk-show-all]\t- Show the whole buffer.
\\[timbuk-hide-other-defuns]\
\t- Hide everything but the current function (function under the cursor).
\\[timbuk-outline]\t- Leave timbuk-outline-mode."
  (interactive "P")
  (setq timbuk-outline-mode
	(if (null arg) (not timbuk-outline-mode) t))
  (if (boundp 'redraw-mode-line)
      (redraw-mode-line))
  (if timbuk-outline-mode
      (progn
	(setq selective-display t)
	(use-local-map timbuk-outline-map))
    (progn
      (setq selective-display nil)
      (timbuk-show-all)
      (use-local-map timbuk-mode-map))))

(defun timbuk-outline-change (b e timbuk-flag)
  (let ((modp (buffer-modified-p)))
    (unwind-protect
	(subst-char-in-region b e (if (= timbuk-flag ?\n) 
				      ?\^M ?\n) timbuk-flag)
      (set-buffer-modified-p modp))))

(defun timbuk-show-all ()
  "Show all of the text in the buffer."
  (interactive)
  (timbuk-outline-change (point-min) (point-max) ?\n))

(defun timbuk-hide-other-defuns ()
  "Show only the current defun."
  (interactive)
  (save-excursion
    (let ((beg (progn (if (not (looking-at "\\(function\\|procedure\\)\\>"))
			  (timbuk-beg-of-defun))
		      (point)))
	  (end (progn (timbuk-end-of-defun)
		      (backward-sexp 1)
		      (search-forward "\n\\|\^M" nil t)
		      (point)))
	  (opoint (point-min)))
      (goto-char (point-min))

      ;; Hide all functions before current function
      (while (re-search-forward "^\\(function\\|procedure\\)\\>" beg 'move)
	(timbuk-outline-change opoint (1- (match-beginning 0)) ?\^M)
	(setq opoint (point))
	;; Functions may be nested
	(if (> (progn (timbuk-end-of-defun) (point)) beg)
	    (goto-char opoint)))
      (if (> beg opoint)
	  (timbuk-outline-change opoint (1- beg) ?\^M))

      ;; Show current function
      (timbuk-outline-change beg end ?\n)
      ;; Hide nested functions
      (forward-char 1)
      (while (re-search-forward "^\\(function\\|procedure\\)\\>" end 'move)
	(setq opoint (point))
	(timbuk-end-of-defun)
	(timbuk-outline-change opoint (point) ?\^M))

      (goto-char end)
      (setq opoint end)

      ;; Hide all function after current function
      (while (re-search-forward "^\\(function\\|procedure\\)\\>" nil 'move)
	(timbuk-outline-change opoint (1- (match-beginning 0)) ?\^M)
	(setq opoint (point))
	(timbuk-end-of-defun))
      (timbuk-outline-change opoint (point-max) ?\^M)

      ;; Hide main program
      (if (< (progn (forward-line -1) (point)) end)
	  (progn
	    (goto-char beg)
	    (timbuk-end-of-defun)
	    (backward-sexp 1)
	    (timbuk-outline-change (point) (point-max) ?\^M))))))

(defun timbuk-outline-next-defun ()
  "Move to next function/procedure, hiding all others."
  (interactive)
  (timbuk-end-of-defun)
  (timbuk-hide-other-defuns))

(defun timbuk-outline-prev-defun ()
  "Move to previous function/procedure, hiding all others."
  (interactive)
  (timbuk-beg-of-defun)
  (timbuk-hide-other-defuns))

(defun timbuk-outline-goto-defun ()
  "Move to specified function/procedure, hiding all others."
  (interactive)
  (timbuk-goto-defun)
  (timbuk-hide-other-defuns))

(provide 'timbuk)

;;; timbuk.el ends here